Merge branch 'c++-build'

CMakeLists.txt

@@ -92,6 +92,20 @@ IF (NOT GUILE_EXECUTABLE)
   MESSAGe (SEND_ERROR "The guile executable was not found, but is required. Please set GUILE_EXECUTABLE.")
 ENDIF (NOT GUILE_EXECUTABLE)
 
+#BOOST
+SET (Boost_USE_STATIC_LIBS OFF)
+SET (Boost_USE_MULTITHREADED ON)
+SET (Boost_USE_STATIC_RUNTIME OFF)
+FIND_PACKAGE (Boost 1.50.0 REQUIRED COMPONENTS chrono date-time filesystem log program_options regex signals system test)
+
+IF (Boost_FOUND)
+    include_directories(${Boost_INCLUDE_DIRS})
+    add_executable(progname file1.cxx file2.cxx)
+    target_link_libraries(progname ${Boost_LIBRARIES})
+ELSE (Boost_FOUND)
+    MESSAGE (SEND_ERROR "Boost 1.50.0 or later is not installed, and is required. Please install it and ensure that the following libraries are built: chrono, date-time, filesystem, log, program_options, regex, signals, system, and test.")
+ENDIF (Boost_FOUND)
+
 # ############################################################
 
 # libdbi

README.dependencies

@@ -69,6 +69,7 @@ libgnomecanvas		2.0
 [lib]goffice		0.7.0
 libxml2			2.5.10
 libxslt
+boost			1.50.0
 swig			2.0.10			Only required to build from git
 						or SVN.
 webkit			1.0

configure.ac

@@ -61,6 +61,8 @@ AC_PROG_CC
 AM_PROG_CC_C_O
 AC_GNU_SOURCE
 AC_PROG_INTLTOOL
+# Ensure the compiler supports C++ 11:
+AX_CXX_COMPILE_STDCXX_11(ext)
 
 
 AC_SUBST(GNUCASH_MAJOR_VERSION)
@@ -119,6 +121,15 @@ AC_COMPILE_IFELSE(
 AC_MSG_RESULT([$ac_cv_CLANG])
 AM_CONDITIONAL([CLANG], [test "x$ac_cv_CLANG" = "xyes"])
 
+###--------------------------------------------------------
+### Begin C++ dependencies
+###--------------------------------------------------------
+AC_MSG_CHECKING(Boost >= 1.50.0)
+AX_BOOST_BASE([1.50.0], [ac_cv_BOOST=yes], [ac_cv_BOOST=no])
+AC_MSG_RESULT($ac_cv_BOOST)
+if test x$ac_cv_BOOST != xyes; then
+    AC_MSG_ERROR([Boost 1.50.0 or later was not found and is required to build GnuCash])
+fi
 ###--------------------------------------------------------
 ### Optionally enable gtkmm plugin (requires c++ compiler)
 ###--------------------------------------------------------
@@ -726,9 +737,21 @@ AC_ARG_ENABLE( debug,
 
 AC_ARG_ENABLE( profile,
   [AS_HELP_STRING([--enable-profile],[compile with profiling set])],
-  CFLAGS="${CFLAGS} -pg"
-  CXXFLAGS="${CXXFLAGS} -pg"
-  LDFLAGS="${LDFLAGS} -pg")
+  AM_CFLAGS="${AM_CFLAGS} -pg"
+  AM_CXXFLAGS="${AM_CXXFLAGS} -pg"
+  AM_LDFLAGS="${AM_LDFLAGS} -pg")
+
+###---------------------------------------------------------------------------
+### Google Profiler Support: https://code.google.com/p/gperftools/
+###---------------------------------------------------------------------------
+enable_google_profile=no
+AC_ARG_ENABLE( google-profiler,
+  [AS_HELP_STRING([--enable-google-profiler], [link in Google Performance Tools profiler; allows enabling profiling by setting $CPUPROFILE=/path/to/logfile.])],
+  [AC_MSG_CHECKING([Google PerfTools Profiler])
+   AC_CHECK_LIB([profiler], enable_google_profile=yes)],
+  [AC_MSG_WARN([Google Profiling Enabled but the library wasn\'t found.])
+])
+AM_CONDITIONAL(WITH_GOOGLE_PROFILER, [test x$enable_google_profile = xyes])
 
 ### --------------------------------------------------------------------------
 ### Register2
@@ -1159,6 +1182,7 @@ then
 
   GNOME=1
   AC_DEFINE(GNOME,,using GNOME)
+  AM_CXXFLAGS="${AM_CXXFLAGS} -Wall"
 
 else
   # GNOME_COMPILE_WARNINGS will add -Wall; no need to set it again.
@@ -1293,8 +1317,10 @@ if test ${GCC}x = yesx
 then
   warnFLAGS=
   warnXXFLAGS=
+  #We have a lot of unused variables. Don't warn until someone gets
+  #around to cleaning them up.
   AM_CFLAGS="${AM_CFLAGS} -Wno-unused"
-  AM_CXXFLAGS="${AM_CXXFLAGS} -Wno-unused"
+  AM_CXXFLAGS="${AM_CXXFLAGS} -Wno-unused -Wno-deprecated-register"
   # other flags...
   # These next two are included in the GNOME_COMPILE_WARNINGS
   #warnFLAGS="${warnFLAGS} -Wmissing-prototypes"
@@ -1329,29 +1355,19 @@ then
       fi
     ])
 
-  # For gcc >= 3.4.x, specifically enable the new warning switch
-  # -Wdeclaration-after-statement in order to preserve source code
-  # compatibility to gcc 2.95 and other compilers.
-
-  if test "`echo ${GCC_VERSION} | cut -d. -f1`" -eq 3; then
-    # This is gcc 3.x.x
-    if test "`echo ${GCC_VERSION} | cut -d. -f2`" -ge 4; then
-      # This is gcc >= 3.4.x
-      warnFLAGS="${warnFLAGS} -Wdeclaration-after-statement"
-    fi
-  elif test "`echo ${GCC_VERSION} | cut -d. -f1`" -ge 4; then
-         # This is gcc >= 4.x.x
-         warnFLAGS="${warnFLAGS} -Wdeclaration-after-statement -Wno-pointer-sign"
-         # rpmbuild on FC4 forces this flag. Only add it when optimizing
-	 cflags_save="$CFLAGS"
-	 CFLAGS="$AM_CFLAGS $CFLAGS -Werror -D_FORTIFY_SOURCE=2"
-	 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
+  warnFLAGS="${warnFLAGS} -Wdeclaration-after-statement -Wno-pointer-sign"
+  # rpmbuild on FC4 forces this flag. Can't hurt to always compile with it.
+  cflags_save="$CFLAGS"
+  CFLAGS="$AM_CFLAGS $CFLAGS -Werror -D_FORTIFY_SOURCE=2"
+  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 #include <stdio.h>
 	 ]],
-	  [[ printf( "%s\n", "Hello World!");]])],
-            [warnFLAGS="${warnFLAGS} -D_FORTIFY_SOURCE=2"])
-	 CFLAGS="$cflags_save"
-  fi
+	 [[ printf( "%s\n", "Hello World!");]])],
+	 [warnFLAGS="${warnFLAGS} -D_FORTIFY_SOURCE=2"
+	 AC_MSG_RESULT(OK)],
+	 [AC_MSG_RESULT(No)])
+  CFLAGS="$cflags_save"
+
   AM_CFLAGS="${warnFLAGS} ${AM_CFLAGS}"
   AM_CXXFLAGS="${warnXXFLAGS} ${AM_CXXFLAGS}"
 else

macros/ax_cxx_compile_stdcxx_11.m4

@@ -0,0 +1,142 @@
+# ============================================================================
+#  http://www.gnu.org/software/autoconf-archive/ax_cxx_compile_stdcxx_11.html
+# ============================================================================
+#
+# SYNOPSIS
+#
+#   AX_CXX_COMPILE_STDCXX_11([ext|noext],[mandatory|optional])
+#
+# DESCRIPTION
+#
+#   Check for baseline language coverage in the compiler for the C++11
+#   standard; if necessary, add switches to CXXFLAGS to enable support.
+#
+#   The first argument, if specified, indicates whether you insist on an
+#   extended mode (e.g. -std=gnu++11) or a strict conformance mode (e.g.
+#   -std=c++11).  If neither is specified, you get whatever works, with
+#   preference for an extended mode.
+#
+#   The second argument, if specified 'mandatory' or if left unspecified,
+#   indicates that baseline C++11 support is required and that the macro
+#   should error out if no mode with that support is found.  If specified
+#   'optional', then configuration proceeds regardless, after defining
+#   HAVE_CXX11 if and only if a supporting mode is found.
+#
+# LICENSE
+#
+#   Copyright (c) 2008 Benjamin Kosnik <bkoz@redhat.com>
+#   Copyright (c) 2012 Zack Weinberg <zackw@panix.com>
+#   Copyright (c) 2013 Roy Stogner <roystgnr@ices.utexas.edu>
+#   Copyright (c) 2014 Alexey Sokolov <sokolov@google.com>
+#
+#   Copying and distribution of this file, with or without modification, are
+#   permitted in any medium without royalty provided the copyright notice
+#   and this notice are preserved. This file is offered as-is, without any
+#   warranty.
+
+#serial 4
+
+m4_define([_AX_CXX_COMPILE_STDCXX_11_testbody], [[
+  template <typename T>
+    struct check
+    {
+      static_assert(sizeof(int) <= sizeof(T), "not big enough");
+    };
+
+    struct Base {
+    virtual void f() {}
+    };
+    struct Child : public Base {
+    virtual void f() override {}
+    };
+
+    typedef check<check<bool>> right_angle_brackets;
+
+    int a;
+    decltype(a) b;
+
+    typedef check<int> check_type;
+    check_type c;
+    check_type&& cr = static_cast<check_type&&>(c);
+
+    auto d = a;
+    auto l = [](){};
+]])
+
+AC_DEFUN([AX_CXX_COMPILE_STDCXX_11], [dnl
+  m4_if([$1], [], [],
+        [$1], [ext], [],
+        [$1], [noext], [],
+        [m4_fatal([invalid argument `$1' to AX_CXX_COMPILE_STDCXX_11])])dnl
+  m4_if([$2], [], [ax_cxx_compile_cxx11_required=true],
+        [$2], [mandatory], [ax_cxx_compile_cxx11_required=true],
+        [$2], [optional], [ax_cxx_compile_cxx11_required=false],
+        [m4_fatal([invalid second argument `$2' to AX_CXX_COMPILE_STDCXX_11])])
+  AC_LANG_PUSH([C++])dnl
+  ac_success=no
+  AC_CACHE_CHECK(whether $CXX supports C++11 features by default,
+  ax_cv_cxx_compile_cxx11,
+  [AC_COMPILE_IFELSE([AC_LANG_SOURCE([_AX_CXX_COMPILE_STDCXX_11_testbody])],
+    [ax_cv_cxx_compile_cxx11=yes],
+    [ax_cv_cxx_compile_cxx11=no])])
+  if test x$ax_cv_cxx_compile_cxx11 = xyes; then
+    ac_success=yes
+  fi
+
+  m4_if([$1], [noext], [], [dnl
+  if test x$ac_success = xno; then
+    for switch in -std=gnu++11 -std=gnu++0x; do
+      cachevar=AS_TR_SH([ax_cv_cxx_compile_cxx11_$switch])
+      AC_CACHE_CHECK(whether $CXX supports C++11 features with $switch,
+                     $cachevar,
+        [ac_save_CXXFLAGS="$CXXFLAGS"
+         CXXFLAGS="$CXXFLAGS $switch"
+         AC_COMPILE_IFELSE([AC_LANG_SOURCE([_AX_CXX_COMPILE_STDCXX_11_testbody])],
+          [eval $cachevar=yes],
+          [eval $cachevar=no])
+         CXXFLAGS="$ac_save_CXXFLAGS"])
+      if eval test x\$$cachevar = xyes; then
+        CXXFLAGS="$CXXFLAGS $switch"
+        ac_success=yes
+        break
+      fi
+    done
+  fi])
+
+  m4_if([$1], [ext], [], [dnl
+  if test x$ac_success = xno; then
+    for switch in -std=c++11 -std=c++0x; do
+      cachevar=AS_TR_SH([ax_cv_cxx_compile_cxx11_$switch])
+      AC_CACHE_CHECK(whether $CXX supports C++11 features with $switch,
+                     $cachevar,
+        [ac_save_CXXFLAGS="$CXXFLAGS"
+         CXXFLAGS="$CXXFLAGS $switch"
+         AC_COMPILE_IFELSE([AC_LANG_SOURCE([_AX_CXX_COMPILE_STDCXX_11_testbody])],
+          [eval $cachevar=yes],
+          [eval $cachevar=no])
+         CXXFLAGS="$ac_save_CXXFLAGS"])
+      if eval test x\$$cachevar = xyes; then
+        CXXFLAGS="$CXXFLAGS $switch"
+        ac_success=yes
+        break
+      fi
+    done
+  fi])
+  AC_LANG_POP([C++])
+  if test x$ax_cxx_compile_cxx11_required = xtrue; then
+    if test x$ac_success = xno; then
+      AC_MSG_ERROR([*** A compiler with support for C++11 language features is required.])
+    fi
+  else
+    if test x$ac_success = xno; then
+      HAVE_CXX11=0
+      AC_MSG_NOTICE([No compiler with C++11 support was found])
+    else
+      HAVE_CXX11=1
+      AC_DEFINE(HAVE_CXX11,1,
+                [define if the compiler supports basic C++11 syntax])
+    fi
+
+    AC_SUBST(HAVE_CXX11)
+  fi
+])

macros/m4_ax_boost_base.m4

@@ -0,0 +1,272 @@
+# ===========================================================================
+#       http://www.gnu.org/software/autoconf-archive/ax_boost_base.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+#   AX_BOOST_BASE([MINIMUM-VERSION], [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
+#
+# DESCRIPTION
+#
+#   Test for the Boost C++ libraries of a particular version (or newer)
+#
+#   If no path to the installed boost library is given the macro searchs
+#   under /usr, /usr/local, /opt and /opt/local and evaluates the
+#   $BOOST_ROOT environment variable. Further documentation is available at
+#   <http://randspringer.de/boost/index.html>.
+#
+#   This macro calls:
+#
+#     AC_SUBST(BOOST_CPPFLAGS) / AC_SUBST(BOOST_LDFLAGS)
+#
+#   And sets:
+#
+#     HAVE_BOOST
+#
+# LICENSE
+#
+#   Copyright (c) 2008 Thomas Porschberg <thomas@randspringer.de>
+#   Copyright (c) 2009 Peter Adolphs
+#
+#   Copying and distribution of this file, with or without modification, are
+#   permitted in any medium without royalty provided the copyright notice
+#   and this notice are preserved. This file is offered as-is, without any
+#   warranty.
+
+#serial 23
+
+AC_DEFUN([AX_BOOST_BASE],
+[
+AC_ARG_WITH([boost],
+  [AS_HELP_STRING([--with-boost@<:@=ARG@:>@],
+    [use Boost library from a standard location (ARG=yes),
+     from the specified location (ARG=<path>),
+     or disable it (ARG=no)
+     @<:@ARG=yes@:>@ ])],
+    [
+    if test "$withval" = "no"; then
+        want_boost="no"
+    elif test "$withval" = "yes"; then
+        want_boost="yes"
+        ac_boost_path=""
+    else
+        want_boost="yes"
+        ac_boost_path="$withval"
+    fi
+    ],
+    [want_boost="yes"])
+
+
+AC_ARG_WITH([boost-libdir],
+        AS_HELP_STRING([--with-boost-libdir=LIB_DIR],
+        [Force given directory for boost libraries. Note that this will override library path detection, so use this parameter only if default library detection fails and you know exactly where your boost libraries are located.]),
+        [
+        if test -d "$withval"
+        then
+                ac_boost_lib_path="$withval"
+        else
+                AC_MSG_ERROR(--with-boost-libdir expected directory name)
+        fi
+        ],
+        [ac_boost_lib_path=""]
+)
+
+if test "x$want_boost" = "xyes"; then
+    boost_lib_version_req=ifelse([$1], ,1.20.0,$1)
+    boost_lib_version_req_shorten=`expr $boost_lib_version_req : '\([[0-9]]*\.[[0-9]]*\)'`
+    boost_lib_version_req_major=`expr $boost_lib_version_req : '\([[0-9]]*\)'`
+    boost_lib_version_req_minor=`expr $boost_lib_version_req : '[[0-9]]*\.\([[0-9]]*\)'`
+    boost_lib_version_req_sub_minor=`expr $boost_lib_version_req : '[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\)'`
+    if test "x$boost_lib_version_req_sub_minor" = "x" ; then
+        boost_lib_version_req_sub_minor="0"
+        fi
+    WANT_BOOST_VERSION=`expr $boost_lib_version_req_major \* 100000 \+  $boost_lib_version_req_minor \* 100 \+ $boost_lib_version_req_sub_minor`
+    AC_MSG_CHECKING(for boostlib >= $boost_lib_version_req)
+    succeeded=no
+
+    dnl On 64-bit systems check for system libraries in both lib64 and lib.
+    dnl The former is specified by FHS, but e.g. Debian does not adhere to
+    dnl this (as it rises problems for generic multi-arch support).
+    dnl The last entry in the list is chosen by default when no libraries
+    dnl are found, e.g. when only header-only libraries are installed!
+    libsubdirs="lib"
+    ax_arch=`uname -m`
+    case $ax_arch in
+      x86_64|ppc64|s390x|sparc64|aarch64)
+        libsubdirs="lib64 lib lib64"
+        ;;
+    esac
+
+    dnl allow for real multi-arch paths e.g. /usr/lib/x86_64-linux-gnu. Give
+    dnl them priority over the other paths since, if libs are found there, they
+    dnl are almost assuredly the ones desired.
+    AC_REQUIRE([AC_CANONICAL_HOST])
+    libsubdirs="lib/${host_cpu}-${host_os} $libsubdirs"
+
+    case ${host_cpu} in
+      i?86)
+        libsubdirs="lib/i386-${host_os} $libsubdirs"
+        ;;
+    esac
+
+    dnl first we check the system location for boost libraries
+    dnl this location ist chosen if boost libraries are installed with the --layout=system option
+    dnl or if you install boost with RPM
+    if test "$ac_boost_path" != ""; then
+        BOOST_CPPFLAGS="-I$ac_boost_path/include"
+        for ac_boost_path_tmp in $libsubdirs; do
+                if test -d "$ac_boost_path"/"$ac_boost_path_tmp" ; then
+                        BOOST_LDFLAGS="-L$ac_boost_path/$ac_boost_path_tmp"
+                        break
+                fi
+        done
+    elif test "$cross_compiling" != yes; then
+        for ac_boost_path_tmp in /usr /usr/local /opt /opt/local ; do
+            if test -d "$ac_boost_path_tmp/include/boost" && test -r "$ac_boost_path_tmp/include/boost"; then
+                for libsubdir in $libsubdirs ; do
+                    if ls "$ac_boost_path_tmp/$libsubdir/libboost_"* >/dev/null 2>&1 ; then break; fi
+                done
+                BOOST_LDFLAGS="-L$ac_boost_path_tmp/$libsubdir"
+                BOOST_CPPFLAGS="-I$ac_boost_path_tmp/include"
+                break;
+            fi
+        done
+    fi
+
+    dnl overwrite ld flags if we have required special directory with
+    dnl --with-boost-libdir parameter
+    if test "$ac_boost_lib_path" != ""; then
+       BOOST_LDFLAGS="-L$ac_boost_lib_path"
+    fi
+
+    CPPFLAGS_SAVED="$CPPFLAGS"
+    CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
+    export CPPFLAGS
+
+    LDFLAGS_SAVED="$LDFLAGS"
+    LDFLAGS="$LDFLAGS $BOOST_LDFLAGS"
+    export LDFLAGS
+
+    AC_REQUIRE([AC_PROG_CXX])
+    AC_LANG_PUSH(C++)
+        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
+    @%:@include <boost/version.hpp>
+    ]], [[
+    #if BOOST_VERSION >= $WANT_BOOST_VERSION
+    // Everything is okay
+    #else
+    #  error Boost version is too old
+    #endif
+    ]])],[
+        AC_MSG_RESULT(yes)
+    succeeded=yes
+    found_system=yes
+        ],[
+        ])
+    AC_LANG_POP([C++])
+
+
+
+    dnl if we found no boost with system layout we search for boost libraries
+    dnl built and installed without the --layout=system option or for a staged(not installed) version
+    if test "x$succeeded" != "xyes"; then
+        _version=0
+        if test "$ac_boost_path" != ""; then
+            if test -d "$ac_boost_path" && test -r "$ac_boost_path"; then
+                for i in `ls -d $ac_boost_path/include/boost-* 2>/dev/null`; do
+                    _version_tmp=`echo $i | sed "s#$ac_boost_path##" | sed 's/\/include\/boost-//' | sed 's/_/./'`
+                    V_CHECK=`expr $_version_tmp \> $_version`
+                    if test "$V_CHECK" = "1" ; then
+                        _version=$_version_tmp
+                    fi
+                    VERSION_UNDERSCORE=`echo $_version | sed 's/\./_/'`
+                    BOOST_CPPFLAGS="-I$ac_boost_path/include/boost-$VERSION_UNDERSCORE"
+                done
+            fi
+        else
+            if test "$cross_compiling" != yes; then
+                for ac_boost_path in /usr /usr/local /opt /opt/local ; do
+                    if test -d "$ac_boost_path" && test -r "$ac_boost_path"; then
+                        for i in `ls -d $ac_boost_path/include/boost-* 2>/dev/null`; do
+                            _version_tmp=`echo $i | sed "s#$ac_boost_path##" | sed 's/\/include\/boost-//' | sed 's/_/./'`
+                            V_CHECK=`expr $_version_tmp \> $_version`
+                            if test "$V_CHECK" = "1" ; then
+                                _version=$_version_tmp
+                                best_path=$ac_boost_path
+                            fi
+                        done
+                    fi
+                done
+
+                VERSION_UNDERSCORE=`echo $_version | sed 's/\./_/'`
+                BOOST_CPPFLAGS="-I$best_path/include/boost-$VERSION_UNDERSCORE"
+                if test "$ac_boost_lib_path" = ""; then
+                    for libsubdir in $libsubdirs ; do
+                        if ls "$best_path/$libsubdir/libboost_"* >/dev/null 2>&1 ; then break; fi
+                    done
+                    BOOST_LDFLAGS="-L$best_path/$libsubdir"
+                fi
+            fi
+
+            if test "x$BOOST_ROOT" != "x"; then
+                for libsubdir in $libsubdirs ; do
+                    if ls "$BOOST_ROOT/stage/$libsubdir/libboost_"* >/dev/null 2>&1 ; then break; fi
+                done
+                if test -d "$BOOST_ROOT" && test -r "$BOOST_ROOT" && test -d "$BOOST_ROOT/stage/$libsubdir" && test -r "$BOOST_ROOT/stage/$libsubdir"; then
+                    version_dir=`expr //$BOOST_ROOT : '.*/\(.*\)'`
+                    stage_version=`echo $version_dir | sed 's/boost_//' | sed 's/_/./g'`
+                        stage_version_shorten=`expr $stage_version : '\([[0-9]]*\.[[0-9]]*\)'`
+                    V_CHECK=`expr $stage_version_shorten \>\= $_version`
+                    if test "$V_CHECK" = "1" -a "$ac_boost_lib_path" = "" ; then
+                        AC_MSG_NOTICE(We will use a staged boost library from $BOOST_ROOT)
+                        BOOST_CPPFLAGS="-I$BOOST_ROOT"
+                        BOOST_LDFLAGS="-L$BOOST_ROOT/stage/$libsubdir"
+                    fi
+                fi
+            fi
+        fi
+
+        CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
+        export CPPFLAGS
+        LDFLAGS="$LDFLAGS $BOOST_LDFLAGS"
+        export LDFLAGS
+
+        AC_LANG_PUSH(C++)
+            AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
+        @%:@include <boost/version.hpp>
+        ]], [[
+        #if BOOST_VERSION >= $WANT_BOOST_VERSION
+        // Everything is okay
+        #else
+        #  error Boost version is too old
+        #endif
+        ]])],[
+            AC_MSG_RESULT(yes)
+        succeeded=yes
+        found_system=yes
+            ],[
+            ])
+        AC_LANG_POP([C++])
+    fi
+
+    if test "$succeeded" != "yes" ; then
+        if test "$_version" = "0" ; then
+            AC_MSG_NOTICE([[We could not detect the boost libraries (version $boost_lib_version_req_shorten or higher). If you have a staged boost library (still not installed) please specify \$BOOST_ROOT in your environment and do not give a PATH to --with-boost option.  If you are sure you have boost installed, then check your version number looking in <boost/version.hpp>. See http://randspringer.de/boost for more documentation.]])
+        else
+            AC_MSG_NOTICE([Your boost libraries seems to old (version $_version).])
+        fi
+        # execute ACTION-IF-NOT-FOUND (if present):
+        ifelse([$3], , :, [$3])
+    else
+        AC_SUBST(BOOST_CPPFLAGS)
+        AC_SUBST(BOOST_LDFLAGS)
+        AC_DEFINE(HAVE_BOOST,,[define if the Boost library is available])
+        # execute ACTION-IF-FOUND (if present):
+        ifelse([$2], , :, [$2])
+    fi
+
+    CPPFLAGS="$CPPFLAGS_SAVED"
+    LDFLAGS="$LDFLAGS_SAVED"
+fi
+
+])

src/bin/Makefile.am

@@ -58,6 +58,10 @@ gnucash_LDADD = \
   ${GLIB_LIBS} \
   ${GTK_LIBS}
 
+if WITH_GOOGLE_PROFILER
+gnucash_LDADD += -lprofiler
+endif
+
 GNUCASH_BIN_INSTALL_NAME=`echo ${BIN_NAME} | sed -e '$(transform)'`
 
 gnucash-valgrind: gnucash-valgrind.in ${top_builddir}/config.status Makefile

src/libqof/qof/Makefile.am

@@ -4,17 +4,23 @@ TEST_SUBDIRS = test
 
 lib_LTLIBRARIES = libgnc-qof.la
 
-libgnc_qof_la_LDFLAGS= -version-info $(LIBQOF_LIBRARY_VERSION)
+libgnc_qof_la_LDFLAGS= \
+	-version-info \
+	$(LIBQOF_LIBRARY_VERSION) \
+	$(BOOST_LDFLAGS)
+
 libgnc_qof_common_libs =  \
   $(GLIB_LIBS) \
   $(REGEX_LIBS) \
   $(top_builddir)/lib/libc/libc-missing.la
+
 libgnc_qof_la_LIBADD = $(libgnc_qof_common_libs)
 
 AM_CPPFLAGS = \
   -I$(top_srcdir)/lib/libc \
   -I$(top_srcdir)/src \
-  $(GLIB_CFLAGS)
+  $(GLIB_CFLAGS) \
+  $(BOOST_CPPFLAGS)
 
 libgnc_qof_la_SOURCES =  \
    gnc-date.cpp        \
@@ -103,6 +109,5 @@ test_qofmath_SOURCES = gnc-numeric.cpp
 test_qofmath_CPPFLAGS = $(AM_CPPFLAGS) -DTEST_128_BIT_MULT
 test_qofmath_LDFLAGS = $(libgnc_qof_la_LDFLAGS)
 test_qofmath_LDADD = $(libgnc_qof_common_libs)
-test_qofmath_CXXFLAGS = -Wall -Werror
 
 AM_CPPFLAGS += -DG_LOG_DOMAIN=\"qof\"

src/libqof/qof/test/Makefile.am

@@ -17,6 +17,7 @@ test_qof_SOURCES = \
 	test-qofobject.c \
 	test-qofsession.c \
 	test-qof-string-cache.c \
+	test-gnc-guid.cpp \
 	${top_srcdir}/src/test-core/unittest-support.c
 
 test_qof_HEADERS = \
@@ -38,7 +39,7 @@ test_qof_LDADD = \
 	${top_builddir}/${MODULEPATH}/libgnc-qof.la \
 	$(GLIB_LIBS)
 
-test_qof_CFLAGS = \
+test_qof_CPPFLAGS = \
 	${DEFAULT_INCLUDES} \
 	-I$(top_srcdir)/${MODULEPATH} \
 	-I$(top_srcdir)/src/test-core \

src/libqof/qof/test/test-gnc-guid.cpp

@@ -0,0 +1,160 @@
+/********************************************************************
+ * GLib test suite for guid.cpp                                     *
+ * Copyright 2014 Aaron Laws <dartmetrash@gmail.com>                *
+ * This program is free software; you can redistribute it and/or    *
+ * modify it under the terms of the GNU General Public License as   *
+ * published by the Free Software Foundation; either version 2 of   *
+ * the License, or (at your option) any later version.              *
+ *                                                                  *
+ * This program is distributed in the hope that it will be useful,  *
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of   *
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the    *
+ * GNU General Public License for more details.                     *
+ *                                                                  *
+ * You should have received a copy of the GNU General Public License*
+ * along with this program; if not, you can retrieve it from        *
+ * http://www.gnu.org/licenses/old-licenses/gpl-2.0.html            *
+ * or contact:                                                      *
+ *                                                                  *
+ * Free Software Foundation           Voice:  +1-617-542-5942       *
+ * 51 Franklin Street, Fifth Floor    Fax:    +1-617-542-2652       *
+ * Boston, MA  02110-1301,  USA       gnu@gnu.org                   *
+ ********************************************************************/
+
+extern "C"
+{
+#include <config.h>
+#include <string.h>
+#include <glib.h>
+#include <unittest-support.h>
+void test_suite_gnc_guid (void);
+}
+
+/*Can be included as c++, because it's c++ tolerant*/
+#include "../guid.h"
+
+#include <random>
+#include <sstream>
+#include <iomanip>
+#include <string>
+#include <iostream>
+
+using namespace std;
+
+static const gchar * suitename {"/qof/gnc-guid"};
+
+/*Create a GUID and free it.*/
+static void test_create_gnc_guid (void){
+    GncGUID * guid {guid_malloc ()};
+    g_assert (guid != nullptr);
+    guid_new (guid);
+    /*We apparently don't need to free guid_null (based on its being const)*/
+    const GncGUID * guidnull {guid_null ()};
+    g_assert (!guid_equal (guid, guidnull));
+    guid_free (guid);
+}
+
+/*We create a GUID, create a copy, and compare them to ensure they're not different.*/
+static void test_gnc_guid_copy (void) {
+    GncGUID * guid {guid_malloc ()};
+    g_assert (guid != nullptr);
+    guid_new (guid);
+    GncGUID * cp {guid_copy (guid)};
+    g_assert (guid_equal (guid, cp));
+    guid_free (cp);
+    guid_free (guid);
+}
+
+/* We create a GUID, then convert it to a string using the two methods
+defined in the guid api. We then compare them.*/
+static void test_gnc_guid_to_string (void) {
+    GncGUID * guid {guid_malloc()};
+    g_assert (guid != nullptr);
+    guid_new (guid);
+    string message {" using guid_to_string (deprecated): "};
+    /*don't free the return value of guid_to_string!*/
+    string guidstr {guid_to_string (guid)};
+    g_assert (guidstr.size () == GUID_ENCODING_LENGTH);
+    message += guidstr;
+    g_test_message ("%s", message.c_str ());
+    message = " using guid_to_string_buff: ";
+    gchar guidstrp2 [GUID_ENCODING_LENGTH+1];
+    gchar * ret {guid_to_string_buff (guid, guidstrp2)};
+    g_assert (ret == guidstrp2 + GUID_ENCODING_LENGTH);
+    string guidstr2 {guidstrp2};
+    g_assert (guidstr2.size () == GUID_ENCODING_LENGTH);
+    message += guidstr2;
+    g_test_message ("%s", message.c_str ());
+
+    g_assert (guidstr2 == guidstr);
+    guid_free (guid);
+}
+
+/*We fill a stringstream with random data, convert those to 
+two GUIDs, then ensure that they are equal*/
+static void test_gnc_guid_equals (void) {
+    GncGUID * guid1 {guid_malloc ()};
+    g_assert (guid1 != nullptr);
+    GncGUID * guid2 {guid_malloc ()};
+    g_assert (guid2 != nullptr);
+    GncGUID * guidold {guid_malloc ()};
+    g_assert (guidold != nullptr);
+
+    mt19937 m;
+    uniform_int_distribution<unsigned> dist;
+    /*we use the same seed every time for reproducibility's sake, and
+    for sanity's sake. It may be nerve-wracking for this test to fail
+    only sometimes, or in different ways.*/
+    m.seed (0);
+    unsigned num_tests {200};
+    for (unsigned test {0}; test < num_tests; ++test){
+        ostringstream o;
+        o << hex << setfill ('0') << right;
+        /*Now we put a GUID into the stringstream*/
+        for (unsigned spot {0}; spot < 4; ++spot)
+            o << setw (8) << dist (m);
+        string guids {o.str ()};
+        g_assert (guids.size() == GUID_ENCODING_LENGTH);
+        g_assert (string_to_guid (guids.c_str (), guid1));
+        g_assert (string_to_guid (guids.c_str (), guid2));
+        g_assert (guid_equal (guid1, guid2));
+        /*Assuming that our distribution won't give the same
+        GUID twice in a row.*/
+        g_assert (!guid_equal (guid1, guidold));
+        g_assert (string_to_guid (guids.c_str (), guidold));
+    }
+    guid_free (guidold);
+    guid_free (guid2);
+    guid_free (guid1);
+}
+
+/*We create a new guid, convert it to string, and convert that to
+a guid, ensuring that we end up with an equivalent structure*/
+static void test_gnc_guid_roundtrip (void) {
+    GncGUID * guid1 {guid_malloc ()};
+    g_assert (guid1 != nullptr);
+    GncGUID * guid2 {guid_malloc ()};
+    g_assert (guid2 != nullptr);
+    guid_new (guid1);
+
+    gchar guidstrp [GUID_ENCODING_LENGTH+1];
+    gchar * temp {guid_to_string_buff (guid1, guidstrp)};
+    g_assert (temp == guidstrp + GUID_ENCODING_LENGTH);
+
+    g_assert (string_to_guid (guidstrp, guid2));
+    g_assert (guid_equal (guid1, guid2));
+    guid_free (guid2);
+    guid_free (guid1);
+}
+
+void test_suite_gnc_guid (void)
+{
+    guid_init ();
+    GNC_TEST_ADD_FUNC (suitename, "gnc create guid", test_create_gnc_guid);
+    GNC_TEST_ADD_FUNC (suitename, "gnc copy guid", test_gnc_guid_copy);
+    GNC_TEST_ADD_FUNC (suitename, "gnc guid to string", test_gnc_guid_to_string);
+    GNC_TEST_ADD_FUNC (suitename, "gnc guid equal", test_gnc_guid_equals);
+    GNC_TEST_ADD_FUNC (suitename, "gnc guid string roundtrip", test_gnc_guid_roundtrip);
+    guid_shutdown ();
+}
+

src/libqof/qof/test/test-qof.c

@@ -32,6 +32,7 @@ extern void test_suite_qofobject();
 extern void test_suite_qofsession();
 extern void test_suite_gnc_date();
 extern void test_suite_qof_string_cache();
+extern void test_suite_gnc_guid ( void );
 
 int
 main (int   argc,
@@ -43,6 +44,7 @@ main (int   argc,
 //    g_log_set_always_fatal (0);
     g_test_bug_base("https://bugzilla.gnome.org/show_bug.cgi?id="); /* init the bugzilla URL */
 
+    test_suite_gnc_guid();
     test_suite_qofbook();
     test_suite_qofinstance();
     test_suite_kvp_frame();